Schlagwort-Archive: Datenqualität

Adventskalender am Rathaus. Stollberg, 2012

Erschließungsgeschichten und ihre Geodaten

In Bearbeitung…. Work in progress1

C. F. Vieweg, Chemnitzerstrasse 2

Papier-Großhandlung, 11. Februar 1936, http://digital.slub-dresden.de/id1678186198 (Chemnitz, Leipzig, Erfurt). Chemnitz, 1923, S. 127, http://digital.slub-dresden.de/id480164991/135 (Einträge 1 bis 25 von 2424. Im Volltext?)

Lahmann-Sanatorium

Special:Nearby#/coord/51.064418,13.819727

Hamburgensien

Meta edits

CARLA

Kleinkinder-Bewahranstalten

Zechenregister im Bergarchiv

https://saxarchiv.hypotheses.org/47796

Call for Edits

1. Archive

https://web.archive.org/web/20251211091607/https://osl.hypotheses.org/18957

Bierzeitung in Döbeln

Speiseanstalten & Volksküchen

„zum teil ein alber ding“

Zeithainer Lustlager

Die Begrenzungsobelisken für das Zeithainer Lustlager (Nearby#/coord/51.331944,13.376667) haben noch Pflegebedarf, (Q186062) und (Q49464479): Bezeichnungen, Beschreibungen, Relationen, Geodaten, Commons-Kategorien …

Dann vielleicht auch Nearby-Polygone?

Alexander Wiede in Chemnitz

Theaterstrasse 5, ungefähr 50.8348778,12.9173976. Dort im Einsatz: https://croptool.toolforge.org für das Illustrirte Weihnachts-Buch des Chemnitzer Landboten, Chemnitz : Wiede, 1883.

  • Gebrueder Wiede, Druckerei und Mechanische Weberei, Alt-Chemnitz, Rechnung, 11. Juni 1891
  • Gebrueder Wiede, Druckerei und Mechanische Weberei für Tischdecken, Portieren etc., Alt-Chemnitz, Alt-Chemnitz, Rechnung, 30. Juni 1891
  • Gebrüder Wiede, Alt-Chemnitz, Rechnung, 22. Juli 1891
  • Alexander Wiede, Buchdruckerei und Papierhandlung, Chemnitz, Rechnung, 1910.
  • Alexander Wiede, Chemnitz, Buchdruckerei, Papierhandlung en gros und Detail-Geschäft von Papierwaren, Rechnung, 28.5.1928
  • 100 Jahre Alexander Wiede, in: Chemnitzer Adreßbuch, 1930, http://digital.slub-dresden.de/id349699747-19300000/5
  • Alexander Wiede, Papier- und Druckhaus, Chemnitz, Rechnung, 13.8.1943
  • Alexander Wiede, Papier- und Druckhaus, Chemnitz, Rechnung, 21.8.1943
  • Alexander Wiede, Fachgeschäft für Papier-, Schreib- und Bürobedarf, eigene Buchdruckerei und Buchbinderei, Chemnitz, Quittung, 19.06.1945
  • (…) Land-Bote und General-Anzeiger für Chemnitz und Umgegend [1905-1907]

Camenzer Wochenschrift im Stadtarchiv Kamenz

In der Qid des Verlags C.S. Krausche in Kamenz (Q134931014) fehlen noch Geokoordinaten. Das Stadtarchiv Kamenz bewahrt die Bände, digitalisiert und erschließt sie, Beratung inklusive: Special:Nearby#/coord/51.27001,14.09478.

https://saxorum.hypotheses.org/14510

Dr. phil. Albin König, 1. höhere Bürgerschule in Leipzig2

Die Gartenlaube (1865) b 332

Wikipedia: Erste Leipziger Bürgerschule (Q116916612#P625), Hermann Oskar Zimmermann: Aus Leipzigs Werkstätten der Jugendbildung : Der deutschen Lehrerversammlung ein erster Gruß, in: Die Gartenlaube, 1865.

Museum für Sächsische Volkskunst3

Volkskunst — überraschend anders

https://volkskunst.skd.museum, Wikidata Nearby: 51.0578,13.7439

Striezelmarktforschung, auch Striezelfolgenabschätzung

Ausgangspunkte für Forschungen zum Striezelmarkt verorte ich bei 51.049631,13.737964. Möglich, dass die Idee Striezelfolgenabschätzung nahe der lokalen Zentralbibliothek ploppte (51.0506,13.7388), folglich mit Striezelmarktforschung als eingängiges Synonym. Das erinnere ich aber nicht so genau. Die Technikfolgenabschätzung (Q746994) steht Pate4.

Rathaus in Stollberg (Q49499113)

Beitragsbild: Adventskalender_am_Rathaus._Stollberg_…, von Kora27, 2012, ohne Kamera- oder Objektposition bisher, Wikidata: Special:Nearby#/coord/50.708088,12.777686

Zum Adventskalender 2025

https://osl.hypotheses.org/18957, siehe auch Dörte Böhner: https://weihnachtsleben.de/2025/11/08/adventskalenderliste-2025-ein-bisschen-verruckt-muss-man-sein/

Die Qid mit den Metadaten dieses Blogosts ist www.wikidata.org/wiki/Q137184028.

  1. Kalendergenerator: Advent 2025, https://osl.hypotheses.org/18581[]
  2. Albin König: Der Handel mit Christbäumen in Leipzig : eine historisch-nationalökonomische Studie, 1907, http://digital.slub-dresden.de/id1916845290[]
  3. Deutsche Fotothek: Musterbuch für Hausrat und Spielzeug; unbekannter Verlag/Händler, wohl 1830er Jahre, evtl. für Leipziger Messe, https://www.deutschefotothek.de/documents/obj/72099808[]
  4. Wortbedeutung.info: Pate stehen, https://www.wortbedeutung.info/Pate_stehen/[]
Meglinger, Kaspar: Der Papst. Aus: Bilderzyklus der Spreuerbrücke Luzern.

Nearby-in-time – edit the rabbit hole based on current events

Who are the Cardinal Electors of 2025 papal conclave? A typical question for Wikidata?

On Easter Monday 21 April 2025 Pope Francis died. As it is used to the Roman Catholic Church all living Cardinals has to come as soon as possible to Rome not only to participate in the Pope’s funeral but also to participate in the at least 20 days after the Pope’s death starting conclave. The rules are more or less clear. Active franchise belongs only to a small number of people: Cardinals which have not fulfilled their 80th birthday on the day before the pope died. So the number of 135 electors in the 2025 papal conclave was communicated immediately.
In Wikipedia lists of all living cardinals in several languages available,1 mostly also with a mark of having franchise in the conclave. Also external sources like the well cited and structured database catholic-hierarchy.org publishes such lists.2

Certainly that would be also a classical question to be answered centralized and language independent using Wikidata: Query all living (date of death is missing) cardinals (humans with position held “cardinal” and its sublcasses), which were younger than 80 years on 20 April 2025.

If we ran the following sparql query on 22 April 2025 we received 130 records, so it seemed that five cardinals were missing:

SELECT DISTINCT ?item ?itemLabel ?doB ?alter (YEAR(?alter) AS ?ageYear)  WHERE {
  ?item wdt:P39/wdt:P279* wd:Q45722; wdt:P569 ?doB. 
  FILTER NOT EXISTS {?item wdt:P570 ?doD.}
  BIND( (xsd:dateTime("2025-04-20T00:00:00Z")-(?doB) )/365 AS ?alter)
  FILTER ( ?alter < 80 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}

Query #1: Cardinal Electors of 2025 papal conclave, simple: https://w.wiki/Du2S 3

Improve the query and clean the data!

First of all there are some issues to be improved in the ?item wdt:P39/wdt:P279* wd:Q45722 query part: Cardinal Dolan doesn’t appear in the list because the statement Archbishop of New York has preferred rank and so it overrules all normal ranked statements in a query using wdt: namespace. So we changed this part of the query to ?item p:P39 ?positionStmt. ?positionStmt ps:P39/wdt:P279* wd:Q45722. so we are able to fetch all subclasses of Cardinal item. Through this adoption, the query responds 132 cardinals.

In comparison of the list of living cardinals in German Wikipedia and the query result we had identified five cardinals with missing position held statement. So the query leaded to 137 cardinals, so we made some further comparison:

  • Cadinal Becciu appears in the list but should not because he resigend from cardinal position with all its rights in September 2020. The End Time Qualifer was missing in Wikidata but of course also in the query too.4
  • Archbishop Carlos Escribano Subías had wrongly a cardinal statement.5

So we received the following SPARQL-query containg all the 135 cardinal electors:

#title:Cardinal Electors of 2025 papal conclave
SELECT DISTINCT ?item ?itemLabel ?doB ?age (GROUP_CONCAT(DISTINCT ?positionLabel; SEPARATOR=", ") AS ?positionLabels)   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722.
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position
  FILTER(NOT EXISTS { ?positionStmt pq:P582 ?endTime. })
  FILTER(NOT EXISTS { ?item wdt:P570 ?doD. })
  BIND(ROUND(FLOOR( (xsd:dateTime("2025-04-20T00:00:00Z") - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
GROUP BY ?item ?itemLabel ?doB ?age
ORDER BY ASC(?doB)

Query #2: Cardinal Electors of 2025 papal conclave, improved: https://w.wiki/Du64

Further it is of course possible to query and calculate also the day before the Sedisvacancy started: We query the Pope’s date of death and substract one day – of course this query only works for a Sedisvancy starting due the death of the pope, and won’t be applicable like in the case of resignation as we have seen it in 2013.

#title:Cardinal Electors of 2025 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q450675>
SELECT DISTINCT ?item ?itemLabel ?doB ?age (GROUP_CONCAT(DISTINCT ?positionLabel; SEPARATOR=", ") AS ?positionLabels)   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722.
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD.   
  BIND(?papalDoD-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan)
  FILTER(NOT EXISTS { ?positionStmt pq:P582 ?endTime. })
  FILTER(NOT EXISTS { ?item wdt:P570 ?doD. })
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
GROUP BY ?item ?itemLabel ?doB ?age
ORDER BY ASC(?doB)

Query #3: Cardinal Electors of 2025 papal conclave with direct query of popes date of death: https://w.wiki/Du76 

The Wikidata taxonomy of Cardinals

In the common way we are talking about “Cardinals” which is a position in the catholic church assigned by the pope. If they are younger than 80 years, they have the right to vote a new pope. The cardinals are divied into three classes:

  • Cardinal-bishop
  • Cardinal-priest
  • Cardinal-dean

This classes are mainly honorable and have no impact of the status of the cardinal. Furthermore each cardinal anywhere bishop, priest or dean are assigned as Cardinal-* of a certain titulary church.

In Wikidata there is (decide: currently or the even Wikidata-typical) mess of cardinal positions in the position held statement.

Looking at the 135 Cardinal Electors we see the following contributions. Additionally one Cardinal has to postition as “Cardinal Secretary of State” and the other three single position holders are items created as the specific Cardinal-* of {Titural-Chruch} like the “Cardinal-Bishop of Albano”.

positionLabelNumber of PositionHolders
Cardinal86
cardinal priest41
cardinal-deacon12
Cardinal Secretary of State1
Q1326732871
Q1328515191
Cardinal-Bishop of Albano1
Query #4: Cardinal-Position types of the 2025 Cardinal Electors and their distribution: https://w.wiki/DuCG

As we have shown above, for querying Cardinals the modelling through a subclass of Statement and all the more specific or granular Cardinal items in Wikidata, it isn’t a big problem to make a successful query. But it shows of course a “rabbit hole” for further editing or at least clarify the appropriate data-modell therefore in the community.

Shall we add only “Cardinal” as position held object and add all the further stuff as qualifiers in the statement? Like start-time (date of appointment), appointed through the dedicated pope, even end-time if different to date of death, and also adding the cardinal-class as honorary value and even the titulary church. But maybe for the last two objects we haven’t currently really good properties.

Using the query for historical Conclaves

Extend the query for the 2005 conclave

Let’s have a try and make some necessary adaptions of query#3 to query the list of Cardinal Electors for “historical” conclaves like after the death of Pope John Paul II in 2005. In the queries above we made an assumption which is problematic in the query to be executable in an abstract way: “Only living cardinals are able to vote for a new pope” or in SPARQL: FILTER(NOT EXISTS { ?item wdt:P570 ?doD. })

Especially for the last two conclaves we have the situation that we have to deal with the date of death of cardinals more precisly. Because a cardinal could have died before he reached 80th birthday, or even a cardinal who was voting for Benedicte XVI in 2025 is still alive today: So we have the situation that in the list of cardinals in 2005 we have both cardinals with or without a current date of death: So we implemented the following hack:

OPTIONAL{?item wdt:P570 ?doD.}
BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  • OPTIONAL{} allows to query cardinal whether alive or dead
  • BIND(IF()[...]) creates as variable ?calculatedDoD which is at least filled with the Pope`s date of Death
  • so we are now able to make greater than FILTER() based on date comparison for all cardinals.

On 25 April 2025 we received 80 Cardinals in the following Query (so there are 37 Cardinals missing in the list 6:

#title:Cardinal Electors of 2005 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q989>
SELECT DISTINCT ?item ?itemLabel ?doB ?doD  ?age   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722.
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD.   
  BIND(?papalDoD-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan)
  FILTER(NOT EXISTS { ?positionStmt pq:P582 ?endTime. })
  OPTIONAL{ ?positionStmt pq:P580 ?startTime. }
  FILTER(?startTime < ?DayBeforeSedisVacan)
  OPTIONAL{?item wdt:P570 ?doD.}
  BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
  FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
ORDER BY ASC(?doB)
Query #5: Cardinal Electors for 2005 Conclave, improved Date of Death handling for Cardinals: https://w.wiki/DuNN 

A main reason for the difference of 37 Cardinals due to the manually curated list in Wikipedia and the query above could be identified in the problematic handling of the position held statement. Missing start and end time qualifier or the granular modelling of cardinal-hierarchy-titles with mis-leading end-time dates leads to a small result set. So the following query is exposed in the position-held start and end time handling and returns 112 items:

#title:Cardinal Electors of 2005 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q989>
SELECT DISTINCT ?item ?itemLabel ?doB ?doD  ?age   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722. #Query Cardinals with all its subclasses
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD.  # Query Pope's date of death
  BIND(?papalDoD-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan) #Calculate the Day of Sedisvacancy
  #Query start and end time of Cardinal position
  OPTIONAL { ?positionStmt pq:P580 ?startTime. }
  OPTIONAL { ?positionStmt pq:P582 ?endTime. }
  #if no end time, add a fictional endtime
  BIND(IF(BOUND(?endTime),?endTime,?papalDoD) AS ?calculatedEndTime) 
  #if no start time, add a fictional startitime
  BIND(IF(BOUND(?startTime),?startTime,?papalDoD-"P2D"^^xsd:duration) AS ?calculatedstartTime)
  #The person should be assigend as cardinal before the Sedisvancy started, an potential end time has to be after the Sedisvacancy started
  FILTER(?calculatedstartTime < ?DayBeforeSedisVacan)
  FILTER(?calculatedEndTime > ?DayBeforeSedisVacan)
  #Exclude Cardinals died before the Sedisvacancy started
  OPTIONAL{?item wdt:P570 ?doD.}
  BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
  FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  #Only cardinals younger than 80 are potential Electors
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
ORDER BY ASC(?doB)
Query #6: Cardinal Electors in 2005 Conclave, improved start/end time qualifier handling (Run the Query)

Extend the query for the 2013 conclave

Lucky that we have with 2013 conclave in the near historical past a special situation. The conclave was formed after the resignation of Pope Benedict XVI. So the calculation of the Date of Sedisvacancy can’t be done be using the pope’s date of death.

We adjust the query with the following lines and make it so agnostic to the fact whether the pope retired from the position or died:

pope: wdt:P570 ?papalDoD; p:P39 ?popePosStmt.
?popePosStmt ps:P39 wd:Q19546.
OPTIONAL { ?popePosStmt pq:P582 ?popeEndTime. }
BIND(IF(BOUND(?popeEndTime),?popeEndTime,?papalDoD) AS ?calculatedDayOfPopesEnd)
#title:Cardinal Electors of 2013 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q2494>
SELECT DISTINCT ?item ?itemLabel ?doB ?doD  ?age   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722. #Query Cardinals with all its subclasses
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD; p:P39 ?popePosStmt. 
  ?popePosStmt ps:P39 wd:Q19546. 
  OPTIONAL { ?popePosStmt pq:P582 ?popeEndTime. }
  BIND(IF(BOUND(?popeEndTime),?popeEndTime,?papalDoD) AS ?calculatedDayOfPopesEnd)
  BIND(?calculatedDayOfPopesEnd-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan) #Calculate the Day of Sedisvacancy
  #Query start and end time of Cardinal position
  OPTIONAL { ?positionStmt pq:P580 ?startTime. }
  OPTIONAL { ?positionStmt pq:P582 ?endTime. }
  BIND(IF(BOUND(?endTime),?endTime,?papalDoD) AS ?calculatedEndTime) #if no end time, add a fictional endtime
  BIND(IF(BOUND(?startTime),?startTime,?papalDoD-"P2D"^^xsd:duration) AS ?calculatedstartTime) #if no start time, add a fictional startitime
  #The person should be assigend as cardinal before the Sedisvancy started, an potential end time has to be after the Sedisvacancy started
  FILTER(?calculatedstartTime < ?DayBeforeSedisVacan)
  FILTER(?calculatedEndTime > ?DayBeforeSedisVacan)
  #Exclude Cardinals died before the Sedisvacancy started
  OPTIONAL{?item wdt:P570 ?doD.}
  BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
  FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  #Only cardinals younger than 80 are potential Electors
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
ORDER BY (?doB)

Query #7: Cardinal Electors in 2013 Conclave, improved "end time" handling of former pope (Run the Query)

Conclusion

The simple question “who are the cardinal electors for a given point in time?” seems certainly a classical task to be answered using a knowledge graph like Wikidata. But actually we see multiple manually edited Wikipedia Pages containing and answering this information. After the death of Pope Francis on 21 April 2025 we have seen that Wikidata was not immediately able to solve the question correctly. Some cardinals were not fully described, one person was wrongly assigned to be one in Wikidata and one cardinal has resigned years before, which has to be modelled correctly and adpoted both in dataset and in the query.

But that’s absolutely not a tragic – because it is Wikidata!

  • You can built more or less easily such a Query to answer the question for the current Cardinal Electors.
  • Even if there is a lack or missing consensus in the data-modelling (like shown in the problematic of the “Cardinal”-position) the SPARQL-Query is able to solve the problem.
  • If the result seems inappropriate Wikidata allows you directly to correct the items yourself.
  • Tools like OpenRefine allows you to make comparision and adjustment of different datasources like Wikipedia tables.7

Cover Image: Meglinger, Kaspar: Der Papst. Bilderzyklus Totentanz. Spreuerbrücke Luzern. (https://n2t.net/ark:/63274/sdl1s902w)

NOTE: Added paragraph about “historical conclaves” on 25 April 2025.

  1. https://de.wikipedia.org/w/index.php?title=Liste_der_lebenden_Kardin%C3%A4le&oldid=255402876 Liste der lebenden Kardinäle, German Wikipedia, accessed 24 April 2025[]
  2. https://www.catholic-hierarchy.org/bishop/scardc1.html Cardinal Electors, catholic-hierarchy.org, accessed 24 April 2025[]
  3. The “historic” result is available in the supplementary dataset materials doi:10.5281/zenodo.15276696[]
  4. https://www.wikidata.org/w/index.php?title=Q1355058&diff=prev&oldid=2340949530 Version history of Cardinal Becciu’s Wikidata-Item, edited on 23 April 2025[]
  5. https://www.wikidata.org/w/index.php?title=Q555422&diff=prev&oldid=2340982098 Version history of Archbishop Carlos Escribano Subías’ Wikidata item, edited on 23 April 2025[]
  6. https://en.wikipedia.org/wiki/Cardinal_electors_in_the_2005_papal_conclave[]
  7. See the used OpenRefine projects for analyze and edit the data doi:10.5281/zenodo.15276696[]
Europe, open access icons

Pages that link to… Parlamentsarchiv (Q53251146) + Parlamentsbibliothek (Q2052886)

Willensbildung in Bearbeitung

Karten*Queries folgen, dann vermutlich deckungsgleich mit der Lage der Landtage und Senate. What links here? Welche Themen, Archivbestände, Publikationen, Metadaten und Anwendungen könnten denn mit den Items der einzelnen Parlamentsbibliotheken und -archive verknüpft werden!? Weitere Datenpflege an den Daten ist sehr willkommen.

Jugendwahlen

Datenpflege fand kürzlich und findet dieser Tage vorläufig1 statt für die

Was machen wir damit noch nearby?


  1. Deutscher Bundesjugendring: Vorläufiges Wahlergebnis der U18-Bundestagswahl, 14. Februar 2025, https://www.dbjr.de/artikel/vorlaeufiges-wahlergebnis-der-u18-bundestagswahl[]
Metadaten, die Kommunalarchive beschreiben, sind digitale öffentliche Güter.

Geographische Koordinaten – in Metadaten, in Karten, Berichten und ihre GeschichteN

Archivdaten verknüpft mit den Geopositionen ihrer Herkunft, der jeweiligen Archiveinrichtung, ihrer Kontexte und Geschichten, danach fragen wir im Aufruf mit Saxorum. Wikidata transportiert geographische Koordinaten mittels Property:P625 direkt, um verknüpfte Daten in Karten zu visualisieren. Blogposts transportieren die Berichte darüber und Geschichten, so die Idee.

Wer arbeitet in Forschungs- und Erschließungsprojekten (oder in GLAM), die unmittelbar oder mittelbar von offenen Metadaten mit Geokoordinaten profitieren? Welche Institutionen-Items in der Abfrageliste w.wiki/Ch9E1 ‘putzen’ wir als nächste, vielleicht sogar ‘Nearby‘?

Mehr Infos: Weiterlesen…

https://saxorum.hypotheses.org/12360
  1. Bearbeitung erfolgte mittels Stapel #242884 “coords for archives from ddb” auf Wikidata sowie Liste von ‘Archiven’ (im weiteren Sinn) in Deutschland ohne DDB-IDhttps://quickstatements.toolforge.org/#/batch/242884 sowie https://qlever.cs.uni-freiburg.de/wikidata/p2PTqS von Awinkler3 am 20. Januar 2025[]