Archiv der Kategorie: Allgemein

Octicons-squirrel.svg

Educational and sociological concepts (Q33104129) need statements

One of my daily obligations is filling ’empty’ Wikidata with some or first statements.

Icon für Tisch mit vier Gedecken

Editiermesser 🎄

Dem geschenkten Editiermesser schaut man nicht in die Versionsgeschichte!

ohne Quelle

Konkurriende Konzepte

Ein Editiermesser ist ein

  • Werkzeug der vegetarischen Küche, heute für Nussbraten (Q4804986)
  • Messgerät für Bearbeitungen mit Geschichte, z.B. in Wikis 1

Bislang kenne und finde ich kein Wikidata-Item für das Konzept ‘Versionsgeschichte’ in “View history*ies”. ‘MediaWiki version history’ (Q15827) meint die Softwareversionen. Der Artikel History of Wikipedia#Past content of Wikipedia beschreibt das längst und gut:

For each Wikipedia article, past versions are accessible through the “View history” link at the top of the page.

https://en.wikipedia.org/w/index.php?title=History_of_Wikipedia&oldid=1327072440#Past_content_of_Wikipedia

Dabei sind Versionsgeschichten so wichtig! Es sollte Normdaten geben für sie. 2

Frohe Weihnachten!


  1. Christian Erlinger, Jens Bemme, “Kamptaler Sakrallandschaften im Wikiversum. Edits mit Versionsgeschichte: Elementarteilchen offener Wissensproduktion am Beispiel eines Citizen Science-Projektes”. LIBREAS. Library Ideas, 44 (2023). https://libreas.eu/ausgabe44/erlinger-bemme/.[]
  2. https://lobid.org/gnd/search?q=Versionsgeschichte[]
Icon für Tisch mit vier Gedecken

Open Senior Open Citizen Scientist roles

One day we’ll might have a variety of roles and their attributes: ages, experiences, openness, ideas, scientific characters, job descriptions, salaries, recognitions, self-conceptions, job offers and questions.1

Senior Open Citizen Scientist is perhaps more of a process of self-discovery or self-identification than a job description.


  1. Wikidata: Open Citizen Science, (Q66771716)[]
Illustrationː ein Zwerg durchbricht das Papier, 1890

Open GLAM-Laborantin (d/w/m)

Ein neues Berufsbild? Profession description (Q19275164): People managing, collecting, connecting, publishing, editing and enriching Open GLAM1 objects, contents, data, ideas and links in between galeries, libraries, archives, museums, historical societies and private collections… ‘linked open’.

Subclass or facet of


  1. Vgl. Douglas McCarthy, Editor of Open GLAM Medium | Co-author of bit.ly/OpenGLAMsurvey: https://culturedoug.medium.com/[]
Illustrationː ein Zwerg durchbricht das Papier, 1890

Ziemlich unwahrscheinliche Projekte

Quite unlikely projects

›Mäanderndes Projektmanagement‹ nannten wir Eigenheiten der Selbstorganisation und Projektpraxis in digitalen Kooperationen.1 ›Ziemlich unwahrscheinliche Projekte‹ möchte ich hiermit prägen, selbst zitieren und somit zitierbar machen.

Citizen Science und Crowdsourcing mit offenen Daten ermöglichen ziemlich unwahrscheinliche Projekte: Transkriptionen samt maschinenlesbarer Detailerschließung, Visualisierungen und Analysen… allgemein: Linked Open Data-Anwendungen, für die im GLAM-Normalbetrieb und in anderen öffentlichen Verwaltungen teils Ressourcen fehlen. Kooperation und Arbeitsteilung sind dann potentiell Lösungen: Ideensprints und Hackathons. Transformation entsteht mit der Zeit durch Regelmäßigkeit, Ausdauer und F&E…

Open Citizen Science – Leitbilder für Bibliotheken, 2024, https://osl.hypotheses.org/11829

Wahrscheinlich Ziele

Drei unwahrscheinlichen Produktionen entstanden im Theater Oberhausen und Hamburg ‘aller Krisenstimmung zum Trotz’ gefördert von der Kulturstiftung des Bundes. Sowas!

Ziemlich unwahrscheinliche Projekte sind hier zum Beispiel:

Relevanz

Ziemlich unwahrscheinliche Projekte haben vielleicht Bedeutung für Ziele, Strategien und ihre Entwicklung und Realisierung, für Blue Ocean Editing, oder: Agenda Setting, allgemein: für die Motivation, für innerbetriebliche Zusammenarbeit vielleicht und für lose und zugleich latent un*verbindliche Kooperationen in Langzeitprojekten mit dem Mehraugenprinzip, für Projekt- und Erfolgsberichte oder als rote Fäden in ebensolchen Reflexionen über Methoden im Projektmanagement!?


  1. Flade, Juliane/Bemme, Jens (2024). Mäanderndes Projekt- und Community- Management – was bewirken, mit echten Menschen im Wikiversum. In: Fabian Cremer/ Swantje Dogunke/ Anna Maria Neubert/ Thorsten Wübbena (Eds.), Projektmanagement und Digital Humanities (89-122). Bielefeld: transcript Verlag. https://doi.org/10.14361/9783839469675-004[]
  2. Jens Bemme: Wann korrigieren wir alle gemeinfreien Publikationen aller historischen Geschichtsvereine?, #vBIB24, Dezember 2024, https://de.wikiversity.org/wiki/VBIB/vBIB24/Geschichtsvereine[]
Meglinger, Kaspar: Der Papst. Aus: Bilderzyklus der Spreuerbrücke Luzern.

Nearby-in-time – edit the rabbit hole based on current events

Who are the Cardinal Electors of 2025 papal conclave? A typical question for Wikidata?

On Easter Monday 21 April 2025 Pope Francis died. As it is used to the Roman Catholic Church all living Cardinals has to come as soon as possible to Rome not only to participate in the Pope’s funeral but also to participate in the at least 20 days after the Pope’s death starting conclave. The rules are more or less clear. Active franchise belongs only to a small number of people: Cardinals which have not fulfilled their 80th birthday on the day before the pope died. So the number of 135 electors in the 2025 papal conclave was communicated immediately.
In Wikipedia lists of all living cardinals in several languages available,1 mostly also with a mark of having franchise in the conclave. Also external sources like the well cited and structured database catholic-hierarchy.org publishes such lists.2

Certainly that would be also a classical question to be answered centralized and language independent using Wikidata: Query all living (date of death is missing) cardinals (humans with position held “cardinal” and its sublcasses), which were younger than 80 years on 20 April 2025.

If we ran the following sparql query on 22 April 2025 we received 130 records, so it seemed that five cardinals were missing:

SELECT DISTINCT ?item ?itemLabel ?doB ?alter (YEAR(?alter) AS ?ageYear)  WHERE {
  ?item wdt:P39/wdt:P279* wd:Q45722; wdt:P569 ?doB. 
  FILTER NOT EXISTS {?item wdt:P570 ?doD.}
  BIND( (xsd:dateTime("2025-04-20T00:00:00Z")-(?doB) )/365 AS ?alter)
  FILTER ( ?alter < 80 )
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }
}

Query #1: Cardinal Electors of 2025 papal conclave, simple: https://w.wiki/Du2S 3

Improve the query and clean the data!

First of all there are some issues to be improved in the ?item wdt:P39/wdt:P279* wd:Q45722 query part: Cardinal Dolan doesn’t appear in the list because the statement Archbishop of New York has preferred rank and so it overrules all normal ranked statements in a query using wdt: namespace. So we changed this part of the query to ?item p:P39 ?positionStmt. ?positionStmt ps:P39/wdt:P279* wd:Q45722. so we are able to fetch all subclasses of Cardinal item. Through this adoption, the query responds 132 cardinals.

In comparison of the list of living cardinals in German Wikipedia and the query result we had identified five cardinals with missing position held statement. So the query leaded to 137 cardinals, so we made some further comparison:

  • Cadinal Becciu appears in the list but should not because he resigend from cardinal position with all its rights in September 2020. The End Time Qualifer was missing in Wikidata but of course also in the query too.4
  • Archbishop Carlos Escribano Subías had wrongly a cardinal statement.5

So we received the following SPARQL-query containg all the 135 cardinal electors:

#title:Cardinal Electors of 2025 papal conclave
SELECT DISTINCT ?item ?itemLabel ?doB ?age (GROUP_CONCAT(DISTINCT ?positionLabel; SEPARATOR=", ") AS ?positionLabels)   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722.
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position
  FILTER(NOT EXISTS { ?positionStmt pq:P582 ?endTime. })
  FILTER(NOT EXISTS { ?item wdt:P570 ?doD. })
  BIND(ROUND(FLOOR( (xsd:dateTime("2025-04-20T00:00:00Z") - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
GROUP BY ?item ?itemLabel ?doB ?age
ORDER BY ASC(?doB)

Query #2: Cardinal Electors of 2025 papal conclave, improved: https://w.wiki/Du64

Further it is of course possible to query and calculate also the day before the Sedisvacancy started: We query the Pope’s date of death and substract one day – of course this query only works for a Sedisvancy starting due the death of the pope, and won’t be applicable like in the case of resignation as we have seen it in 2013.

#title:Cardinal Electors of 2025 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q450675>
SELECT DISTINCT ?item ?itemLabel ?doB ?age (GROUP_CONCAT(DISTINCT ?positionLabel; SEPARATOR=", ") AS ?positionLabels)   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722.
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD.   
  BIND(?papalDoD-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan)
  FILTER(NOT EXISTS { ?positionStmt pq:P582 ?endTime. })
  FILTER(NOT EXISTS { ?item wdt:P570 ?doD. })
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
GROUP BY ?item ?itemLabel ?doB ?age
ORDER BY ASC(?doB)

Query #3: Cardinal Electors of 2025 papal conclave with direct query of popes date of death: https://w.wiki/Du76 

The Wikidata taxonomy of Cardinals

In the common way we are talking about “Cardinals” which is a position in the catholic church assigned by the pope. If they are younger than 80 years, they have the right to vote a new pope. The cardinals are divied into three classes:

  • Cardinal-bishop
  • Cardinal-priest
  • Cardinal-dean

This classes are mainly honorable and have no impact of the status of the cardinal. Furthermore each cardinal anywhere bishop, priest or dean are assigned as Cardinal-* of a certain titulary church.

In Wikidata there is (decide: currently or the even Wikidata-typical) mess of cardinal positions in the position held statement.

Looking at the 135 Cardinal Electors we see the following contributions. Additionally one Cardinal has to postition as “Cardinal Secretary of State” and the other three single position holders are items created as the specific Cardinal-* of {Titural-Chruch} like the “Cardinal-Bishop of Albano”.

positionLabelNumber of PositionHolders
Cardinal86
cardinal priest41
cardinal-deacon12
Cardinal Secretary of State1
Q1326732871
Q1328515191
Cardinal-Bishop of Albano1
Query #4: Cardinal-Position types of the 2025 Cardinal Electors and their distribution: https://w.wiki/DuCG

As we have shown above, for querying Cardinals the modelling through a subclass of Statement and all the more specific or granular Cardinal items in Wikidata, it isn’t a big problem to make a successful query. But it shows of course a “rabbit hole” for further editing or at least clarify the appropriate data-modell therefore in the community.

Shall we add only “Cardinal” as position held object and add all the further stuff as qualifiers in the statement? Like start-time (date of appointment), appointed through the dedicated pope, even end-time if different to date of death, and also adding the cardinal-class as honorary value and even the titulary church. But maybe for the last two objects we haven’t currently really good properties.

Using the query for historical Conclaves

Extend the query for the 2005 conclave

Let’s have a try and make some necessary adaptions of query#3 to query the list of Cardinal Electors for “historical” conclaves like after the death of Pope John Paul II in 2005. In the queries above we made an assumption which is problematic in the query to be executable in an abstract way: “Only living cardinals are able to vote for a new pope” or in SPARQL: FILTER(NOT EXISTS { ?item wdt:P570 ?doD. })

Especially for the last two conclaves we have the situation that we have to deal with the date of death of cardinals more precisly. Because a cardinal could have died before he reached 80th birthday, or even a cardinal who was voting for Benedicte XVI in 2025 is still alive today: So we have the situation that in the list of cardinals in 2005 we have both cardinals with or without a current date of death: So we implemented the following hack:

OPTIONAL{?item wdt:P570 ?doD.}
BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  • OPTIONAL{} allows to query cardinal whether alive or dead
  • BIND(IF()[...]) creates as variable ?calculatedDoD which is at least filled with the Pope`s date of Death
  • so we are now able to make greater than FILTER() based on date comparison for all cardinals.

On 25 April 2025 we received 80 Cardinals in the following Query (so there are 37 Cardinals missing in the list 6:

#title:Cardinal Electors of 2005 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q989>
SELECT DISTINCT ?item ?itemLabel ?doB ?doD  ?age   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722.
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD.   
  BIND(?papalDoD-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan)
  FILTER(NOT EXISTS { ?positionStmt pq:P582 ?endTime. })
  OPTIONAL{ ?positionStmt pq:P580 ?startTime. }
  FILTER(?startTime < ?DayBeforeSedisVacan)
  OPTIONAL{?item wdt:P570 ?doD.}
  BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
  FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
ORDER BY ASC(?doB)
Query #5: Cardinal Electors for 2005 Conclave, improved Date of Death handling for Cardinals: https://w.wiki/DuNN 

A main reason for the difference of 37 Cardinals due to the manually curated list in Wikipedia and the query above could be identified in the problematic handling of the position held statement. Missing start and end time qualifier or the granular modelling of cardinal-hierarchy-titles with mis-leading end-time dates leads to a small result set. So the following query is exposed in the position-held start and end time handling and returns 112 items:

#title:Cardinal Electors of 2005 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q989>
SELECT DISTINCT ?item ?itemLabel ?doB ?doD  ?age   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722. #Query Cardinals with all its subclasses
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD.  # Query Pope's date of death
  BIND(?papalDoD-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan) #Calculate the Day of Sedisvacancy
  #Query start and end time of Cardinal position
  OPTIONAL { ?positionStmt pq:P580 ?startTime. }
  OPTIONAL { ?positionStmt pq:P582 ?endTime. }
  #if no end time, add a fictional endtime
  BIND(IF(BOUND(?endTime),?endTime,?papalDoD) AS ?calculatedEndTime) 
  #if no start time, add a fictional startitime
  BIND(IF(BOUND(?startTime),?startTime,?papalDoD-"P2D"^^xsd:duration) AS ?calculatedstartTime)
  #The person should be assigend as cardinal before the Sedisvancy started, an potential end time has to be after the Sedisvacancy started
  FILTER(?calculatedstartTime < ?DayBeforeSedisVacan)
  FILTER(?calculatedEndTime > ?DayBeforeSedisVacan)
  #Exclude Cardinals died before the Sedisvacancy started
  OPTIONAL{?item wdt:P570 ?doD.}
  BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
  FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  #Only cardinals younger than 80 are potential Electors
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
ORDER BY ASC(?doB)
Query #6: Cardinal Electors in 2005 Conclave, improved start/end time qualifier handling (Run the Query)

Extend the query for the 2013 conclave

Lucky that we have with 2013 conclave in the near historical past a special situation. The conclave was formed after the resignation of Pope Benedict XVI. So the calculation of the Date of Sedisvacancy can’t be done be using the pope’s date of death.

We adjust the query with the following lines and make it so agnostic to the fact whether the pope retired from the position or died:

pope: wdt:P570 ?papalDoD; p:P39 ?popePosStmt.
?popePosStmt ps:P39 wd:Q19546.
OPTIONAL { ?popePosStmt pq:P582 ?popeEndTime. }
BIND(IF(BOUND(?popeEndTime),?popeEndTime,?papalDoD) AS ?calculatedDayOfPopesEnd)
#title:Cardinal Electors of 2013 papal conclave
PREFIX pope: <http://www.wikidata.org/entity/Q2494>
SELECT DISTINCT ?item ?itemLabel ?doB ?doD  ?age   WHERE {
  ?item p:P39 ?positionStmt.
  ?positionStmt ps:P39/wdt:P279* wd:Q45722. #Query Cardinals with all its subclasses
  ?item wdt:P569 ?doB.
  ?positionStmt ps:P39 ?position.
  pope: wdt:P570 ?papalDoD; p:P39 ?popePosStmt. 
  ?popePosStmt ps:P39 wd:Q19546. 
  OPTIONAL { ?popePosStmt pq:P582 ?popeEndTime. }
  BIND(IF(BOUND(?popeEndTime),?popeEndTime,?papalDoD) AS ?calculatedDayOfPopesEnd)
  BIND(?calculatedDayOfPopesEnd-"P1D"^^xsd:duration AS ?DayBeforeSedisVacan) #Calculate the Day of Sedisvacancy
  #Query start and end time of Cardinal position
  OPTIONAL { ?positionStmt pq:P580 ?startTime. }
  OPTIONAL { ?positionStmt pq:P582 ?endTime. }
  BIND(IF(BOUND(?endTime),?endTime,?papalDoD) AS ?calculatedEndTime) #if no end time, add a fictional endtime
  BIND(IF(BOUND(?startTime),?startTime,?papalDoD-"P2D"^^xsd:duration) AS ?calculatedstartTime) #if no start time, add a fictional startitime
  #The person should be assigend as cardinal before the Sedisvancy started, an potential end time has to be after the Sedisvacancy started
  FILTER(?calculatedstartTime < ?DayBeforeSedisVacan)
  FILTER(?calculatedEndTime > ?DayBeforeSedisVacan)
  #Exclude Cardinals died before the Sedisvacancy started
  OPTIONAL{?item wdt:P570 ?doD.}
  BIND(IF(BOUND(?doD),?doD,?papalDoD) AS ?calculatedDoD)
  FILTER(?calculatedDoD > ?DayBeforeSedisVacan)
  #Only cardinals younger than 80 are potential Electors
  BIND(ROUND(FLOOR( (?DayBeforeSedisVacan - ?doB) / 365.25) )  AS ?age)
  FILTER(?age < 80 )
  SERVICE wikibase:label { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul". 
    ?item rdfs:label ?itemLabel.
    ?position rdfs:label ?positionLabel.
  }  
}
ORDER BY (?doB)

Query #7: Cardinal Electors in 2013 Conclave, improved "end time" handling of former pope (Run the Query)

Conclusion

The simple question “who are the cardinal electors for a given point in time?” seems certainly a classical task to be answered using a knowledge graph like Wikidata. But actually we see multiple manually edited Wikipedia Pages containing and answering this information. After the death of Pope Francis on 21 April 2025 we have seen that Wikidata was not immediately able to solve the question correctly. Some cardinals were not fully described, one person was wrongly assigned to be one in Wikidata and one cardinal has resigned years before, which has to be modelled correctly and adpoted both in dataset and in the query.

But that’s absolutely not a tragic – because it is Wikidata!

  • You can built more or less easily such a Query to answer the question for the current Cardinal Electors.
  • Even if there is a lack or missing consensus in the data-modelling (like shown in the problematic of the “Cardinal”-position) the SPARQL-Query is able to solve the problem.
  • If the result seems inappropriate Wikidata allows you directly to correct the items yourself.
  • Tools like OpenRefine allows you to make comparision and adjustment of different datasources like Wikipedia tables.7

Cover Image: Meglinger, Kaspar: Der Papst. Bilderzyklus Totentanz. Spreuerbrücke Luzern. (https://n2t.net/ark:/63274/sdl1s902w)

NOTE: Added paragraph about “historical conclaves” on 25 April 2025.

  1. https://de.wikipedia.org/w/index.php?title=Liste_der_lebenden_Kardin%C3%A4le&oldid=255402876 Liste der lebenden Kardinäle, German Wikipedia, accessed 24 April 2025[]
  2. https://www.catholic-hierarchy.org/bishop/scardc1.html Cardinal Electors, catholic-hierarchy.org, accessed 24 April 2025[]
  3. The “historic” result is available in the supplementary dataset materials doi:10.5281/zenodo.15276696[]
  4. https://www.wikidata.org/w/index.php?title=Q1355058&diff=prev&oldid=2340949530 Version history of Cardinal Becciu’s Wikidata-Item, edited on 23 April 2025[]
  5. https://www.wikidata.org/w/index.php?title=Q555422&diff=prev&oldid=2340982098 Version history of Archbishop Carlos Escribano Subías’ Wikidata item, edited on 23 April 2025[]
  6. https://en.wikipedia.org/wiki/Cardinal_electors_in_the_2005_papal_conclave[]
  7. See the used OpenRefine projects for analyze and edit the data doi:10.5281/zenodo.15276696[]
Zone of proximal development Label-free.svg

Ich habe eine neue Position. #xEditsXnearby

Theorie

  • Positioning theory is a theory in social psychology that characterizes interactions between individuals. “Position” can be defined as an alterable collection of beliefs of an individual with regards to their rights, duties, and obligations. “Positioning” is the mechanism through which roles are assigned or denied, either to oneself or others.1
  • The zone of proximal development (ZPD) is a concept in educational psychology that represents the space between what a learner is capable of doing unsupported and what the learner cannot do even with support. It is the range where the learner is able to perform, but only with support from a teacher or a peer with more knowledge or expertise. This person is known as the “more knowledgable other.”2

Praxis

Ich fragte mich beim Lesen beider Artikel, ob und wie wir die Theorien und Ansätze3 samt ihrer noch relativ leeren Datenobjekte mit z.B. Datendenken lernen und Geo-Koordinaten anderer Datenobjekte in Verbindung bringen… Zu Ende schreiben und trainieren will ich aber gerade eigentlich was anderes. Drum lasse ich das hier mal so stehen.


  1. Wikipedia: https://en.wikipedia.org/w/index.php?title=Positioning_theory, (Q104869574)[]
  2. Wikipedia: https://en.wikipedia.org/wiki/Zone_of_proximal_development, (Q1053392)[]
  3. Beitragsbild: Zone_of_proximal_development_Label-free.svg, CC BY-SA 4.0 by Blacktc via Wikimedia Commons, in: Category:Zone_of_proximal_development[]
Europe, open access icons

Open GLAM Lab_or Kulturhauptstadt

Chemnitz liegt nah, nun eine Hauptstadt. Wie Nova Gorica und Gorizia, aber die sind physisch noch nicht mit dem Jobticket zu erreichen. Bis Kaunas verfliegen circa 17 Stunden. Nach Tartu fährt man ab da noch ein Stück weiter. Bibliotheken gibt’s dort, um zu schreiben1, WLAN und Archive.

Eine Analogie besteht, wenn zwei Dinge oder Sachverhalte sich in einigen Merkmalen ähnlich sind, auch wenn sie sich in anderen Merkmalen unterscheiden können. https://de.wikipedia.org/w/index.php?title=Analogie_(Rhetorik)&oldid=219256471

In solchen Hauptstädten entsteht mit viel Energie, Vorbereitungen und Geld haufenweise Material Kulturgut: Reiseziele, Begegnung, Bilder, Erinnerungen, Publikationen, Anlässe für eigene Edits; jeder Ort ein ‘Nearby‘.

Die BUGAs, hier voraussichtlich im Jahr 2033, haben denselben Sinn. Bis dahin verliehrt man sich entdeckt man andere und doch ähnliche Ziele: Analogien. Zum Beispiel in benachbarten Landschaften: Lettische Regionalarchive stecken in Wikidata, teils noch ohne Koordinaten. Kaunas hat ein ‘Regional State Archive’, (Q20503772). Das Archiv in Cēsis transportiert nun die eigenen Ortsdaten in (Q81181144); auch das Historische Staatsarchiv in Rīga, (Q16361750), ein ‘Sehnsuchtsarchiv’ potentiell für Baltisches Radfahrerwissen!2 So kommt man rum. Gesucht hatte ich anfangs das Archiv in Valga, Estland.

Edits for European Capitals of Culture

Chemnitz sehe ich 2025. ‘Capitals of Culture’ mit Edits erst digital und eins oder zwei Jahre nach dem Hauptstadtjahr zu bereisen, ist potentiell eine weitere Strategie, um sie zu besuchen. Das Programm ist dann zu Ende, seine und andere Spuren findet man für eigene Edits vor Ort immer.3

Commons-Kategorien und Datenobjekte sind bei Bedarf schnell angelegt, für Bilder und andere Inhalte:

Ich kann mir ‘regionale Open GLAM Labs’ nur so denken: gelegentlich unterwegs in lokalen und regionalen, persönlichen und transnationalen Linkzusammenhängen, mal vor Ort, oft digital – so oder so nebenan, also ‘nearby’.

https://saxorum.hypotheses.org/5170

Beitragsbild: Europe_oaicons.png, Julian Kücklich, CC0, Open Access Icons for Open Access Office Brandenburg via Wikimedia Commons

  1. Jens Bemme, Martin Munke: Open Citizen Science: Leitbild für kuratorische Praktiken in Wissenschaftlichen Bibliotheken. In: Bibliotheken als Orte kuratorischer Praxis, Klaus Ulrich Werner (Hrsg.), Berlin, Boston: De Gruyter Saur, 2021, S. 165-200. https://doi.org/10.1515/9783110673722-013[]
  2. Vgl. Baltischer Radfahrer-Kalender für das Jahr 1897. – Vorwort, II. Jahrgang, 4. November 2022, https://nfg.hypotheses.org/3260 sowie Latvijas Nacionālā bibliotēka, Rīgā: ‘LNB:Letonikas un Baltijas lasītava’ 000601617, http://primolatvija.hosted.exlibrisgroup.com/permalink/f/3skv0k/371KISC_AlephLNC04-000601617[]
  3. Kaunas 2022: Kaunas 2022 Contemporary capital : European Capital of Culture, Final stage bid book 2017, https://katalog.slub-dresden.de/id/0-1907115722; Kaunas – European capital of culture 2022 : youth programme methodology, https://katalog.slub-dresden.de/id/0-1908998938; Kaunas – European capital of culture 2022, https://katalog.slub-dresden.de/id/0-1908998660; Kaunas – European capital of culture 2022, https://katalog.slub-dresden.de/id/0-1908998660[]